Conversor de temperatura

Planteamiento

Desarrollar un algoritmo en pseudocódigo que permita convertir grados Fahrenheit a grados Celsius y viceversa. Realizar las operaciones en funciones, una para convertir Fahrenheit a Celsius y otra para convertir Celsius a Fahrenheit.

Ejemplos

*** Conversor de temperatura ***

Selecciona una opción:
1. Fahrenheit a Celsius
2. Celsius a Fahrenheit
> 5
Ingresa la temperatura convertir:
> 50

Opción no válida. Por favor, selecciona 1 o 2.

---

*** Conversor de temperatura ***

Selecciona una opción:
1. Fahrenheit a Celsius
2. Celsius a Fahrenheit
> 1
Ingresa la temperatura convertir:
> 80

80°F = 26.6666666667°C

---

*** Conversor de temperatura ***

Selecciona una opción:
1. Fahrenheit a Celsius
2. Celsius a Fahrenheit
> 2
Ingresa la temperatura convertir:
> 28

28°C = 82.4°F

Solución

Algoritmo en Pseudocódigo

Algoritmo conversor_temperatura
    
    Escribir "*** Conversor de temperatura ***"
    
    Escribir ""
    Escribir "Selecciona una opción:"
    Escribir "1. Fahrenheit a Celsius"
    Escribir "2. Celsius a Fahrenheit"
    Leer opcionSeleccionada
    
    Escribir "Ingresa la temperatura convertir:"
    Leer temperatura
    Escribir ""
    
    Segun opcionSeleccionada Hacer
        1:
            resultado = convertirFahrenheitACelsius(temperatura)
            Escribir temperatura, "°F = ", resultado, "°C"
        2:
            resultado = convertirCelsiusAFahrenheit(temperatura)
            Escribir temperatura, "°C = ", resultado, "°F"
        De Otro Modo:
            Escribir "Opción no válida. Por favor, selecciona 1 o 2."
    Fin Segun
    
FinAlgoritmo

Funcion resultado <- convertirFahrenheitACelsius (temperatura)
    resultado = (temperatura - 32) * 5/9
Fin Funcion

Funcion resultado <- convertirCelsiusAFahrenheit (temperatura)
    resultado = (temperatura * 9/5) + 32
Fin Funcion

Diagramas de Flujo

---

---