Empresa de transporte

Planteamiento

Rogelio es el propietario de una empresa de transporte llamada "Transportes La Joya" ubicada en la comunidad La Joya. Su empresa se especializa en el traslado de personas hacia comunidades cercanas, cada una de las cuales cuenta con una abreviatura para facilitar su identificación. Con el objetivo de contribuir a la comunidad, Rogelio ofrece descuentos en el costo del transporte a personas de la tercera edad y a estudiantes, siempre y cuando muestren una credencial que lo acredite. A las personas de la tercera edad les cobra solo el 50%, mientras que a los estudiantes les aplica un descuento del 30%.

Con base en la siguiente tabla que muestra las comunidades junto con sus respectivas abreviaturas y la tarifa para cada destino, desarrollar un algoritmo en pseudocódigo que solicite el nombre del pasajero, el tipo de pasajero (para ver si hay que aplicar algún descuento) y el destino (la abreviatura). Al finalizar, se deberá generar el boleto correspondiente para el pasajero, incluyendo el nombre de la empresa, el nombre del pasajero, el tipo de pasajero, la ruta (origen y destino), la tarifa (subtotal), el descuento (si aplica) y el costo final del boleto.

Comunidad	Abreviatura	Tarifa
Villa Esperanza	VE	$30.00
Pueblo Sereno	PS	$149.00
Alameda del Sol	AS	$75.50
Oasis Tranquilo	OT	$45.90
Monteverde	MV	$250.00

Ejemplos

Datos de entrada: Marta García, Estudiante, SF

Destino incorrecto

---

Datos de entrada: Luis Mendoza, Regular, ps

*************************************************
               Transportes La Joya

Pasajero: Luis Mendoza
Tipo de Pasajero: Regular

Ruta: La Joya - Pueblo Sereno (PS)

Subtotal: $149
Descuento: $0
TOTAL: $149

## Feliz Viaje ##

************************************************

---

Datos de entrada: Ana Sánchez, Estudiante, MV

*************************************************
               Transportes La Joya

Pasajero: Ana Sánchez
Tipo de Pasajero: Estudiante

Ruta: La Joya - Monteverde (MV)

Subtotal: $250
Descuento: $75
TOTAL: $175

## Feliz Viaje ##

*************************************************

---

Datos de entrada: Juan Rodríguez, Tercera edad, AS

*************************************************
               Transportes La Joya

Pasajero: Juan Rodríguez
Tipo de Pasajero: Tercera Edad

Ruta: La Joya - Alameda del Sol (AS)

Subtotal: $75.5
Descuento: $37.75
TOTAL: $37.75

## Feliz Viaje ##

*************************************************

Solución

Algoritmo en Pseudocódigo

Algoritmo empresa_transporte
    
    Escribir "*** Empresa de transporte ***"
    
    // Datos del Pasajero
    
    Escribir "Ingresa el nombre del pasajero:"
    Leer nombrePasajero
    
    Limpiar Pantalla
    
    // Tipo de Pasajero
    
    Escribir "Ingresa el tipo de pasajero"
    Escribir "-> 1 para Estudiante"
    Escribir "-> 2 para Persona de la tercera edad"
    Escribir "-> 0 o cualquier otro valor para Pasajero Regular"
    Leer tipoPasajero
    
    Definir tipoPasajeroTexto Como Cadena // Descripción del tipo de pasajero
    Definir porcentajeDescuento Como Entero
    
    Segun tipoPasajero Hacer
        1:
            tipoPasajeroTexto = "Estudiante"
            porcentajeDescuento = 30
        2:
            tipoPasajeroTexto = "Tercera Edad"
            porcentajeDescuento = 50
        De Otro Modo:
            tipoPasajeroTexto = "Regular"
            porcentajeDescuento = 0
    Fin Segun
    
    Limpiar Pantalla
    
    // Destino
    
    Escribir "Ingresa el destino"
    Escribir "-> VE para Villa Esperanza"
    Escribir "-> PS para Pueblo Sereno"
    Escribir "-> AS para Alameda del Sol"
    Escribir "-> OT para Oasis Tranquilo"
    Escribir "-> MV para Monteverde"
    Leer destino
    destino = Mayusculas(destino)
    
    Definir nombreDestino Como Cadena // Nombre completo del destino
    Definir tarifa Como Real
    
    Segun destino Hacer
        "VE":
            nombreDestino = "Villa Esperanza"
            tarifa = 30.00
        "PS":
            nombreDestino = "Pueblo Sereno"
            tarifa = 149.00
        "AS":
            nombreDestino = "Alameda del Sol"
            tarifa = 75.50
        "OT":
            nombreDestino = "Oasis Tranquilo"
            tarifa = 45.90
        "MV":
            nombreDestino = "Monteverde"
            tarifa = 250.00
        De Otro Modo:
            nombreDestino = "--"
    Fin Segun
    
    Limpiar Pantalla
    
    // Cálculos
    descuento = (tarifa / 100) * porcentajeDescuento
    tarifaFinal = tarifa - descuento
    
    // Generación del Boleto
    
    Si nombreDestino == "--" Entonces
        Escribir "Destino incorrecto"
    SiNo
        
        Escribir "*************************************************"
        Escribir "               Transportes La Joya               "
        Escribir ""
        Escribir "Pasajero: ", nombrePasajero
        Escribir "Tipo de Pasajero: ", tipoPasajeroTexto
        Escribir ""
        Escribir "Ruta: La Joya - ", nombreDestino, " (", destino, ")"
        Escribir ""
        Escribir "Subtotal: $", tarifa
        Escribir "Descuento: $", descuento
        Escribir "TOTAL: $", tarifaFinal
        Escribir ""
        Escribir "## Feliz Viaje ##"
        Escribir ""
        Escribir "*************************************************"
        
    Fin Si
    
FinAlgoritmo

Diagrama de Flujo